# Maintainer: Markus Pesch <markus.pesch@cryptic.systems>

pkgname=docker-pushrm
pkgver=1.9.0
pkgrel=2
pkgdesc='"Docker Push Readme" - a Docker CLI plugin to update container repo docs'
arch=('x86_64')
url=https://github.com/christian-korneck/docker-pushrm
license=('MIT')
makedepends=('go')
source=("https://github.com/christian-korneck/docker-pushrm/archive/v${pkgver}.zip")
sha512sums=('aef19964c740b4d9b512b696759cd4b31793ced91f066864e534242d74694a796ee9930a809c2b5a6779238e32572642ab05fa5a7f8cf1062d0a9dd5f40c52d8')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}

  export GOPATH="${srcdir}"

  env | sort | grep -E '^C?GO'

  go mod download -modcacherw
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # https://wiki.archlinux.org/title/Go_package_guidelines
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOPATH="${srcdir}"

  go build \
    -trimpath \
    -buildmode=pie \
    -mod=readonly \
    -modcacherw \
    -ldflags "-linkmode external" \
    -o $pkgname \
    .
}

package() {
  install -D --mode=0755 "${srcdir}/${pkgname}-${pkgver}/${pkgname}" "${pkgdir}/usr/lib/docker/cli-plugins/${pkgname}"
  install -D --mode=0644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}