# Maintainer: Markus Pesch <markus.pesch@cryptic.systems>

pkgname=kyverno-cli-bin
_pkgname=kyverno-cli
pkgver=1.18.0 # renovate: datasource=github-tags depName=kyverno/kyverno extractVersion='^v?(?<version>.*)$'
pkgrel=1
pkgdesc="Kubernetes Native Policy Management - CLI"
arch=('aarch64' 'x86_64')
url="https://github.com/kyverno/kyverno"
license=("Apache-2.0")
conflicts=(kyverno-git)
provides=(kyverno-git)

source_x86_64=(
  "https://github.com/kyverno/kyverno/releases/download/v${pkgver}/${_pkgname}_v${pkgver}_linux_x86_64.tar.gz"
)

source_aarch64=(
  "https://github.com/kyverno/kyverno/releases/download/v${pkgver}/${_pkgname}_v${pkgver}_linux_arm64.tar.gz"
)

sha256sums_aarch64=('37697771e1cc92daf73bebde4eb304691af09e07a4278cc82062e829c8475cec')
sha256sums_x86_64=('3aa7b7aa68732fd6bc5732f1030d0ed12e1b0ffe7dbac5f5aa21fd8695718904')

build() {
  $srcdir/kyverno completion bash > kyverno.bash
  $srcdir/kyverno completion fish > kyverno.fish
  $srcdir/kyverno completion zsh > kyverno.zsh
}

package() {
  # binary
  install -D --mode 0755 "kyverno" "$pkgdir/usr/bin/kyverno"

  # completions
  install -D --mode 0644 "kyverno.bash" "$pkgdir/usr/share/bash-completion/completions/kyverno"
  install -D --mode 0644 "kyverno.fish" "$pkgdir/usr/share/fish/vendor_completions.d/kyverno.fish"
  install -D --mode 0644 "kyverno.zsh" "$pkgdir/usr/share/zsh/site-functions/_kyverno"

  # license
  install -D --mode 0755 "LICENSE" "$pkgdir/usr/share/licenses/kyverno/LICENSE"
}